Une boucle de comptage

Une boucle de comptage est une boucle qui va incrémenter un chiffre / nombre autant de fois que souhaité.

Style

POUR $maVariable EGALE A CHIFFRE JUSQUE UN_AUTRE_CHIFFRE {
 
ON AUGMENTE DE 1
}

Notez que l'on peut changer le pas, c'est à dire le saut entre 2 nombres avec l'opérateur STEP (pas). Style

POUR $maVariable EGALE A CHIFFRE JUSQUE UN_AUTRE_CHIFFRE PAS VALEUR_DU_PAS {
 
ON AUGMENTE DE LA VALEUR_DU_PAS
}

Avec la syntaxe de kturtle

for variable = number to number step number { ... }

Demander d'analyse ces 2 morceaux de code

for $i = 1 to 10 {
 message $i
}

for $i = 0 to 10 step 2 {
 message $i
}

Comme précédemment, après un temps de saisie, d'observation, d'analyse puis de modification, on réalise une mise en commun et on commente le fonctionnement de cette boucle.

Rappelons aux élèves le code réalisé pour la construction de tables de Pythagore et essayons de l'optimiser avec ce qui a été mis en évidence plus haut (la boucle de comptage).

A savoir Avec le code suivant

reset
spritehide
 
$Y = 25
$nombre = 1
$facteur = ask "Quelle table construire ?"
 
 
repeat 14 {
	# On se positionne
	go 25, $Y
	# On affiche la formule magique
	print $nombre + " X " + $facteur + " =	" + $nombre * $facteur
	# On met à jour la variable $nombre
	$nombre = $nombre + 1
	# On descend d'une ligne dans l'affichage
	$Y = $Y + 10
}

Au besoin, inscrire ou projeter ce code en phase commune au tableau. Le ré-analyser voir les lignes spécifiques à l'incrémentation du nombre de départ, les individualiser pour les faire ressortir avec une craie de couleur et demander de les remplacer par une séquence for.

Avec la boucle de comptage, on doit aboutir à un code de ce type.

reset
spritehide
 
$Y = 25
$facteur = ask "Quelle table construire ?"
 
 
for $nombre = 1 to 14 {
	# On se positionne
	go 25, $Y
	# On affiche la formule magique
	print $nombre + " X " + $facteur + " =	" + $nombre * $facteur
	# On descend d'une ligne dans l'affichage
	$Y = $Y + 10
}